Как извлечь данные .gpx с помощью python

Вы можете установить GPXpy

sudo pip install gpxpy

Тогда просто используйте библиотеку:

import gpxpy 
import gpxpy.gpx 

 gpx_file = open('input_file.gpx', 'r') 

    gpx = gpxpy.parse(gpx_file) \
    for track in gpx.tracks: 
      for segment in track.segments: 
    for point in segment.points: 
      print 'Point at ({0},{1}) -> {2}'.format(point.latitude, point.longitude, point.elevation) 

    for waypoint in gpx.waypoints: 
      print 'waypoint {0} -> ({1},{2})'.format(waypoint.name, waypoint.latitude, waypoint.longitude) 

    for route in gpx.routes: 
      print 'Route:' 

Для получения дополнительной информации: https://pypi.python.org/pypi/gpxpy.

С Уважением

GPX — это формат XML, поэтому используйте подходящий модуль, например lxml или включенный ElementTree XML API для анализа данных и последующего вывода в CSV с помощью csv модуля python.

• учебник по lxml.etree
• руководство по ElementTree
• Погружение в Python 3 по обработке XML
• Обработка CSV-файлов в Python

Я также нашел библиотеку синтаксического анализа GPX для Python под названием gpxpy, которая, возможно, предоставляет интерфейс более высокого уровня для данных, содержащихся в GPX-файлы.

Поскольку Мартейн опубликовал ответ на Python и сказал, что Perl превратится в линейный шум, я почувствовал, что есть потребность в ответе на Perl.

В CPAN, каталоге модулей Perl, есть модуль с именем Geo::Gpx. Как уже сказал Мартин, GPX — это формат XML. Но, к счастью, кто-то уже превратил его в модуль, который занимается синтаксическим анализом вместо нас. Все, что нам нужно сделать, это загрузить этот модуль.

Для обработки CSV доступно несколько модулей, но данные в этом XML-файле довольно простые, поэтому он нам не нужен. Мы можем сделать это самостоятельно с помощью встроенного функционала.

Пожалуйста, рассмотрите следующий сценарий. Я дам объяснение через минуту.

use strict;
use warnings;
use Geo::Gpx;
use DateTime;
# Open the GPX file
open my $fh_in, '<', 'fells_loop.gpx';
# Parse GPX
my $gpx = Geo::Gpx->new( input => $fh_in );
# Close the GPX file
close $fh_in;

# Open an output file
open my $fh_out, '>', 'fells_loop.csv';
# Print the header line to the file
print $fh_out "time,lat,lon,ele,name,sym,type,desc\n";

# The waypoints-method of the GEO::GPX-Object returns an array-ref
# which we can iterate in a foreach loop
foreach my $wp ( @{ $gpx->waypoints() } ) {
  # Some fields seem to be optional so they are missing in the hash.
  # We have to add an empty string by iterating over all the possible
  # hash keys to put '' in them.
  $wp->{$_} ||= '' for qw( time lat lon ele name sym type desc );

  # The time is a unix timestamp, which is hard to read.
  # We can make it an ISO8601 date with the DateTime module.
  # We only do it if there already is a time, though.
  if ($wp->{'time'}) {
    $wp->{'time'} = DateTime->from_epoch( epoch => $wp->{'time'} )
                             ->iso8601();
  }
  # Join the fields with a comma and print them to the output file
  print $fh_out join(',', (
    $wp->{'time'},
    $wp->{'lat'},
    $wp->{'lon'},
    $wp->{'ele'},
    $wp->{'name'},
    $wp->{'sym'},
    $wp->{'type'},
    $wp->{'desc'},
  )), "\n"; # Add a newline at the end
}
# Close the output file
close $fh_out;

Давайте рассмотрим это по шагам:

• use strict и use warnings обеспечивает соблюдение правил, таких как объявление переменных, и сообщает вам о распространенных ошибках, которые труднее всего найти.
• use Geo::Gpx и use DateTime — модули, которые мы используем. Geo::Gpx будет заниматься синтаксическим анализом для нас. Нам нужно DateTime, чтобы преобразовать временные метки unix в удобочитаемые даты и время.
• Функция open открывает файл. $fh_in — это переменная, которая содержит дескриптор файла. Файл GPX, который мы хотим прочитать, называется fells_loop.gpx, который я взял на себя смелость позаимствовать у topografix.com. Дополнительную информацию о open можно найти в perlopentut.
• Мы создаем новый объект Geo::Gpx с именем $gpx и используем наш дескриптор файла $fh_in, чтобы сообщить ему, откуда считывать XML-данные. Метод new предоставляется всеми модулями Perl, имеющими объектно-ориентированный интерфейс.
• close закрывает дескриптор файла.
• Следующий open имеет >, чтобы сообщить Perl, что мы хотим записать в этот дескриптор файла.
• Мы print получаем дескриптор файла, помещая его в качестве первого аргумента в print. Обратите внимание, что после дескриптора файла запятая не ставится. \n — это символ новой строки.

• foreach цикл принимает возвращаемое значение waypoints-метода объекта Geo::Gpx . Это значение является ссылкой на массив. Думайте об этом как о массиве, который содержит массивы (см. perlref, если вы хотите узнать больше о ссылках). ). В каждой итерации цикла следующий элемент этого массива ref (который представляет путевую точку в данных GPX) будет помещаться в $wp. Если напечатать с Data::Dumper, это будет выглядеть так:

  $VAR1 = {
        'ele' => '64.008000',
        'lat' => '42.455956',
        'time' => 991452424,
        'name' => 'SOAPBOX',
        'sym' => 'Cemetery',
        'desc' => 'Soap Box Derby Track',
        'lon' => '-71.107483',
        'type' => 'Intersection'
      };
  

• Теперь с постфиксом for немного сложнее. Как мы только что видели, в hashref есть 8 ключей. К сожалению, некоторые из них иногда отсутствуют. Поскольку у нас есть use warnings, мы получим предупреждение, если попытаемся получить доступ к одному из этих отсутствующих значений. Мы должны создать эти ключи и поместить туда пустую строку ''.

  foreach и for полностью взаимозаменяемы в Perl, и оба могут также использоваться в синтаксисе postfix за одним выражением. Мы используем qw-оператор для создания списка, который for будет перебирать. qw — сокращение от слов в кавычках< /strong> и он делает именно это: возвращает список строк в нем, но в кавычках. Мы могли бы также сказать ('time', 'lat', 'long'... ).

  В выражении мы получаем доступ к каждому ключу $wp. $_ — это переменная цикла. В первой итерации он будет содержать «время», затем «лат» и так далее. Поскольку $wp — это хэш-ссылка, нам нужен -> для доступа к его ключам. Фигурные скобки говорят, что это hashref. ||= оператор присваивает значение только нашему элементу хэша ref если это не истинное значение.

• Теперь, если есть значение времени (пустая строка, которую мы только что присвоили, если дата не была установлена, рассматривается как «ничего нет»), мы заменяем метку времени unix на правильную дату. В этом нам помогает DateTime. Метод from_epoch получает временную метку unix в качестве аргумента. Он возвращает объект DateTime, который мы можем напрямую использовать для вызова на нем функции iso8601.

  Это называется цепочкой. Некоторые модули могут это сделать. Это похоже на то, что делают объекты JavaScript jQuery. Временная метка unix в нашем hashref заменяется результатом операции DateTime.

• Теперь мы снова print к нашему файловому дескриптору. join используется для помещения запятых между значениями. Мы также ставим новую строку в конце снова.
• Как только мы закончим с циклом, мы close дескриптор файла.
• Теперь мы закончили! :)